# Applying IF Function in Excel

Learn how to use the Excel IF function with syntax and examples.

## Description

The Microsoft Excel IF function returns one value if a specified condition evaluates to TRUE, or another value if it evaluates to FALSE.

## Syntax

The syntax for the Microsoft Excel IF function is:

`IF( condition, [value_if_true], [value_if_false] )`

### Parameters or Arguments

condition is the value that you want to test.

value_if_true is optional. It is the value that is returned if condition evaluates to TRUE.

value_if_false is optional. It is the value that is return if condition evaluates to FALSE.

## Applies To

The IF function can be used in the following versions of Microsoft Excel:

• Excel 2013, Excel 2011 for Mac, Excel 2010, Excel 2007, Excel 2003, Excel XP, Excel 2000

## Type of Excel Function

The IF function can be used in Microsoft Excel as the following type of function:

• Worksheet function (WS)

## Example (as Worksheet Function)

Let’s look at some Excel IF function examples and explore how you would use the IF function as a worksheet function in Microsoft Excel:

Based on the spreadsheet above, the following Excel IF examples would return:

 =IF(A1>10, “Larger”, “Smaller”) would return “Larger” =IF(A1=20, “Equal”, “Not Equal”) would return “Not Equal” =IF(A2=”Tech on the Net”, 12, 0) would return 12

Learn how to nest multiple IF Functions. (up to 7)

Learn how to nest multiple IF Functions. (more than 7)

Question: In Microsoft Excel, I’d like to use the IF function to create the following logic:

`if C11>=620, and C10="F"or"S", and C4<=\$1,000,000, and C4<=\$500,000, and C7<=85%, and C8<=90%, and C12<=50, and C14<=2, and C15="OO", and C16="N", and C19<=48, and C21="Y", then reference cell A148 on Sheet2. Otherwise, return an empty string.`

Answer: The following formula would accomplish what you are trying to do:

`=IF(AND(C11>=620, OR(C10="F",C10="S"), C4<=1000000, C4<=500000, C7<=0.85, C8<=0.9, C12<=50, C14<=2, C15="OO", C16="N", C19<=48, C21="Y"), Sheet2!A148, "")`

Question: In Microsoft Excel, I’m trying to use the IF function to return 0 if cell A1 is either < 150,000 or > 250,000. Otherwise, it should return A1.

Answer: You can use the OR function to perform an OR condition in the IF function as follows:

`=IF(OR(A1<150000,A1>250000),0,A1)`

In this example, the formula will return 0 if cell A1 was either less than 150,000 or greater than 250,000. Otherwise, it will return the value in cell A1.

Question: In Microsoft Excel, I’m trying to use the IF function to return 25 if cell A1 > 100 and cell B1 < 200. Otherwise, it should return 0.

Answer: You can use the AND function to perform an AND condition in the IF function as follows:

`=IF(AND(A1>100,B1<200),25,0)`

In this example, the formula will return 25 if cell A1 is greater than 100 and cell B1 is less than 200. Otherwise, it will return 0.

Question: In Microsoft Excel, I need to write a formula that works this way:

• IF (cell A1) is less than 20, then times it by 1,
• IF it is greater than or equal to 20 but less than 50, then times it by 2
• IF its is greater than or equal to 50 and less than 100, then times it by 3
• And if it is great or equal to than 100, then times it by 4

Answer: You can write a nested IF statement to handle this. For example:

`=IF(A1<20, A1*1, IF(A1<50, A1*2, IF(A1<100, A1*3, A1*4)))`

Question: In Microsoft Excel, I need a formula in cell C5 that does the following:

• IF A1+B1 <= 4, return \$20
• IF A1+B1 > 4 but <= 9, return \$35
• IF A1+B1 > 9 but <= 14, return \$50
• IF A1+B1 > 15, return \$75

Answer: In cell C5, you can write a nested IF statement that uses the AND function as follows:

`=IF((A1+B1)<=4,20,IF(AND((A1+B1)>4,(A1+B1)<=9),35,IF(AND((A1+B1)>9,(A1+B1)<=14),50,75)))`

Question: In Microsoft Excel, I need a formula that does the following:

• IF the value in cell A1 is BLANK, then return “BLANK”
• IF the value in cell A1 is TEXT, then return “TEXT”
• IF the value in cell A1 is NUMERIC, then return “NUM”

Answer: You can write a nested IF statement that uses the ISBLANK function, the ISTEXT function, and the ISNUMBER function as follows:

`=IF(ISBLANK(A1)=TRUE,"BLANK",IF(ISTEXT(A1)=TRUE,"TEXT",IF(ISNUMBER(A1)=TRUE,"NUM","")))`

Question: In Microsoft Excel, I want to write a formula for the following logic:

• IF R1<0.3 AND R2<0.3 AND R3<0.42 THEN “OK” OTHERWISE “NOT OK”

Answer: You can write an IF statement that uses the AND function as follows:

`=IF(AND(R1<0.3,R2<0.3,R3<0.42),"OK","NOT OK")`

Question: In Microsoft Excel, I need a formula for the following:

• IF cell A1= PRADIP then value will be 100
• IF cell A1= PRAVIN then value will be 200
• IF cell A1= PARTHA then value will be 300
• IF cell A1= PAVAN then value will be 400

Answer: You can write an IF statement as follows:

`=IF(A1="PRADIP",100,IF(A1="PRAVIN",200,IF(A1="PARTHA",300,IF(A1="PAVAN",400,""))))`

Question: In Microsoft Excel, I want to calculate following using an “if” formula:

• if A1<100,000 then A1*.1% but minimum 25
• and if A1>1,000,000 then A1*.01% but maximum 5000

Answer: You can write a nested IF statement that uses the MAX function and the MIN function as follows:

`=IF(A1<100000,MAX(25,A1*0.1%),IF(A1>1000000,MIN(5000,A1*0.01%),""))`

Question: In Microsoft Excel, I am trying to create an IF statement that will repopulate the data from a particular cell if the data from the formula in the current cell equals 0. Below is my attempt at creating an IF statement that would populate the data; however, I was unsuccessful.

`=IF(IF(ISERROR(M24+((L24-S24)/AA24)),"0",M24+((L24-S24)/AA24)))=0,L24)`

The initial part of the formula calculates the EAC (Estimate At completion = AC+(BAC-EV)/CPI); however if the current EV (Earned Value) is zero, the EAC will equal zero. IF the outcome is zero, I would like the BAC (Budget At Completion), currently recorded in another cell (L24), to be repopulated in the current cell as the EAC.

Answer: You can write an IF statement that uses the OR function and the ISERROR function as follows:

`=IF(OR(S24=0,ISERROR(M24+((L24-S24)/AA24))),L24,M24+((L24-S24)/AA24))`

Question: I have been looking at your Excel IF, AND and OR sections and found this very helpful, however I cannot find the right way to write a formula to express if C2 is either 1,2,3,4,5,6,7,8,9 and F2 is F and F3 is either D,F,B,L,R,C then give a value of 1 if not then 0. I have tried many formulas but just can’t get it right, can you help please?

Answer: You can write an IF statement that uses the AND function and the OR function as follows:

`=IF(AND(C2>=1,C2<=9, F2="F",OR(F3="D",F3="F",F3="B",F3="L",F3="R",F3="C")),1,0)`

Question:In Excel, I have a roadspeed of a car in m/s in cell A1 and a drop down menu of different units in C1 (which unclude mph and kmh). I have used the following IF function in B1 to convert the number to the unit selected from the dropdown box:

`=IF(C1="mph","=A1*2.23693629",IF(C1="kmh","A1*3.6"))`

However say if kmh was selected B1 literally just shows A1*3.6 and does not actually calculate it. Is there away to get it to calculate it instead of just showing the text message?

Answer: You are very close with your formula. Because you are performing mathematical operations (such as A1*2.23693629 and A1*3.6), you do not need to surround the mathematical formulas in quotes. Quotes are necessary when you are evaluating strings, not performing math.

Try the following:

`=IF(C1="mph",A1*2.23693629,IF(C1="kmh",A1*3.6))`

Question:For an IF statement in Excel, I want to combine text and a value.

For example, I want to put an equation for work hours and pay. IF I am paid more than I should be, I want it to read how many hours I owe my boss. But if I work more than I am paid for, I want it to read what my boss owes me (hours*Pay per Hour).

I tried the following:

`=IF(A2<0,"I owe boss" abs(A2) "Hours","Boss owes me" abs(A2)*15 "dollars")`

Is it possible or do I have to do it in 2 separate cells? (one for text and one for the value)

Answer: There are two ways that you can concatenate text and values. The first is by using the & character to concatenate:

`=IF(A2<0,"I owe boss " & ABS(A2) & " Hours","Boss owes me " & ABS(A2)*15 &  " dollars")`

Or the second method is to use the CONCATENATE function:

`=IF(A2<0,CONCATENATE("I owe boss ", ABS(A2)," Hours"), CONCATENATE("Boss owes me ", ABS(A2)*15,  " dollars"))`

Question:I have Excel 2000. IF cell A2 is greater than or equal to 0 then add to C1. IF cell B2 is greater than or equal to 0 then subtract from C1. IF both A2 and B2 are blank then equals C1. Can you help me with the IF function on this one?

Answer: You can write a nested IF statement that uses the AND function and the ISBLANK function as follows:

`=IF(AND(ISBLANK(A2)=FALSE,A2>=0),C1+A2, IF(AND(ISBLANK(B2)=FALSE,B2>=0),C1-B2, IF(AND(ISBLANK(A2)=TRUE, ISBLANK(B2)=TRUE),C1,"")))`

Question:How would I write this equation in Excel? IF D12<=0 then D12*L12, IF D12 is > 0 but <=600 then D12*F12, IF D12 is >600 then ((600*F12)+((D12-600)*E12))

Answer: You can write a nested IF statement as follows:

`=IF(D12<=0,D12*L12,IF(D12>600,((600*F12)+((D12-600)*E12)),D12*F12))`

Question:In Excel, I have this formula currently:

`=IF(OR(A1>=40, B1>=40, C1>=40), "20", (A1+B1+C1)-20)`

If one of my salesman does sale for \$40-\$49, then his commission is \$20; however if his/her sale is less (for example \$35) then the commission is that amount minus \$20 (\$35-\$20=\$15). I have 3 columns that are needed based on the type of sale. Only one column per row will be needed. The problem is that, when left blank, the total in the formula cell is -20. I need help setting up this formula so that when the 3 columns are left blank, the cell with the formula is left blank as well.

Answer: Using the AND function and the ISBLANK function, you can write your IF statement as follows:

`=IF(AND(ISBLANK(A1),ISBLANK(B1),ISBLANK(C1)),"",IF(OR(A1>40, B1>40, C1>40), "20", (A1+B1+C1)-20))`

In this formula, we are using the ISBLANK function to check if all 3 cells A1, B1, and C1 are blank, and if they are return a blank value (“”). Then the rest is the formula that you originally wrote.

Question:In Excel, I need to create a simple booking and and out system, that shows a date out and a date back

“A1” = allows person to input date booked out
“A2” =allows person to input date booked back in

“A3″= shows status of product, eg, booked out, overdue return etc.

I can automate A3 with the following IF function:

`=IF(ISBLANK(A2),"booked out","returned")`

But what I cant get to work is if the product is out for 10 days or more, I would like the cell to say “send email”

Can you assist?

`=IF(ISBLANK(A2),IF(TODAY()-A1>10,"send email","booked out"),"returned")`

Question:Using Microsoft Excel, I need a formula in cell U2 that does the following:

```IF the date in E2<=12/31/2010, return T2*0.75
IF the date in E2>12/31/2010 but <=12/31/2011, return T2*0.5
IF the date in E2>12/31/2011, return T2*0```

I tried using the following formula, but it gives me ā#VALUE!ā

`=IF(E2<=DATE(2010,12,31),T2*0.75), IF(AND(E2>DATE(2010,12,31),E2<=DATE(2011,12,31)),T2*0.5,T2*0)`

`=IF(E2<=DATE(2010,12,31),T2*0.75, IF(AND(E2>DATE(2010,12,31),E2<=DATE(2011,12,31)),T2*0.5,T2*0))`

Question:In Excel, I would like to add 60 days if grade is ‘A’, 45 days if grade is ‘B’ and 30 days if grade is ‘C’. It would roughly look something like this, but I’m struggling with commas, brackets, etc.

```(IF C5=A)=DATE(YEAR(B5)+0,MONTH(B5)+0,DAY(B5)+60),
(IF C5=B)=DATE(YEAR(B5)+0,MONTH(B5)+0,DAY(B5)+45),
(IF C5=C)=DATE(YEAR(B5)+0,MONTH(B5)+0,DAY(B5)+30)```

Answer:You should be able to achieve your date calculations with the following formula:

`=IF(C5="A",B5+60,IF(C5="B",B5+45,IF(C5="C",B5+30)))`

Question:In Excel, I am trying to write a function and can’t seem to figure it out. Could you help?

```IF D3 is < 31, then 1.51
IF D3 is between 31-90, then 3.40
IF D3 is between 91-120, then 4.60
IF D3 is > 121, then 5.44```

`=IF(D3>121,5.44,IF(D3>=91,4.6,IF(D3>=31,3.4,1.51)))`

Question:I would like ask a question regarding the IF statement. How would I write in Excel this problem?

I have to check if cell A1 is empty and if not, check if the value is less than equal to 5. Then multiply the amount entered in cell A1 by .60. The answer will be displayed on Cell A2.

Answer:You can write your formula in cell A2 using the IF function and ISBLANK function as follows:

`=IF(AND(ISBLANK(A1)=FALSE,A1<=5),A1*0.6,"")`

Question:In Excel, I’m trying to nest an OR command and I can’t find the proper way to write it. I want the spreadsheet to do the following:

If D6 equals “HOUSE” and C6 equals either “MOUSE” or “CAT”, I want to return the value in cell B6. Otherwise, the formula should return the value “BLANK”.

I tried the following:

`=IF((D6="HOUSE")*(C6="MOUSE")*OR(C6="CAT"));B6;"BLANK")`

If I only ask for HOUSE and MOUSE or HOUSE and CAT, it works, but as soon as I ask for MOUSE OR CAT, it doesn’t work.

Answer:You can write your formula using the AND function and OR function as follows:

`=IF(AND(D6="HOUSE",OR(C6="MOUSE",C6="CAT")),B6,"BLANK")`

This will return the value in B6 if D6 equals “HOUSE” and C6 equals either “MOUSE” or “CAT”. If those conditions are not met, the formula will return the text value of “BLANK”.

Question:In Microsoft Excel, I’m trying to write the following formula:

If cell A1 equals “jaipur”, “udaipur” or “jodhpur”, then cell A2 should display “rajasthan”
If cell A1 equals “bangalore”, “mysore” or “belgum”, then cell A2 should display “karnataka”

`=IF(OR(A1="jaipur",A1="udaipur",A1="jodhpur"),"rajasthan", IF(OR(A1="bangalore",A1="mysore",A1="belgum"),"karnataka"))`

This will return “rajasthan” if A1 equals either “jaipur”, “udaipur” or “jodhpur” and it will return “karnataka” if A1 equals either “bangalore”, “mysore” or “belgum”.

Question:In Microsoft Excel I’m trying to achieve the following with IF function:

If a value in any cell in column F is “food” then add the value of its corresponding cell in column G (eg a corresponding cell for F3 is G3). The IF function is performed in another cell altogether. I can do it for a single pair of cells but I don’t know how to do it for an entire column. Could you help?

At the moment, I’ve got this:

`=IF(F3="food"; G3; 0)`

Answer:This formula can be created using the SUMIF formula instead of using the IF function:

`=SUMIF(F1:F10,"=food",G1:G10)`

This will evaluate the first 10 rows of data in your spreadsheet. You may need to adjust the ranges accordingly.

I notice that you separate your parameters with semi-colons, so you might need to replace the commas in the formula above with semi-colons.

Question:Iām looking for an Exel formula that says:

```If F3 is "H" and E3 is "H", return 1
If F3 is "A" and E3 is "A", return 2
If F3 is "d" and E3 is "d", return 3```

Appreciate if you can help.

Answer:This Excel formula can be created using the AND formula in combination with the IF function:

`=IF(AND(F3="H",E3="H"),1,IF(AND(F3="A",E3="A"),2,IF(AND(F3="d",E3="d"),3,"")))`

We’ve defaulted the formula to return a blank if none of the conditions above are met.

Question:I am trying to get Excel to check different boxes and check if there is text/numbers listed in the cells and then spit out “Complete” if all 5 Boxes have text/Numbers or “Not Complete” if one or more is empty. This is what I have so far and it doesn’t work.

`=IF(OR(ISBLANK(J2),ISBLANK(M2),ISBLANK(R2),ISBLANK (AA2),ISBLANK (AB2)),"Not Complete","")`

Answer:First, you are correct in using the ISBLANK function, however, you have a space between ISBLANK and (AA2), as well as ISBLANK and (AB2). This might seem insignificant, but Excel can be very picky and will return a #NAME? error. So first you need to eliminate those spaces.

Next, you need to change the ELSE condition of your IF function to return “Complete”.

You should be able to modify your formula as follows:

`=IF(OR(ISBLANK(J2),ISBLANK(M2),ISBLANK(R2),ISBLANK(AA2),ISBLANK(AB2)), "Not Complete", "Complete")`

Now if any of the cell J2, M2, R2, AA2, or AB2 are blank, the formula will return “Not Complete”. If all 5 cells have a value, the formula will return “Complete”.

Question:I’m very new to the Excel world, and I’m trying to figure out how to set up the proper formula for an If/then cell.

What I’m trying for is:

• If B2’s value is 1 to 5, then multiply E2 by .77
• If B2’s value is 6 to 10, then multiply E2 by .735
• If B2’s value is 11 to 19, then multiply E2 by .7
• If B2’s value is 20 to 29, then multiply E2 by .675
• If B2’s value is 30 to 39, then multiply E2 by .65

I’ve tried a few different things thinking I was on the right track based on the IF, and AND function tutorials here, but I can’t seem to get it right.

Answer:To write your IF formula, you need to nest multiple IF functions together in combination with the AND function.

The following formula should work for what you are trying to do:

`=IF(AND(B2>=1, B2<=5), E2*0.77, IF(AND(B2>=6, B2<=10), E2*0.735, IF(AND(B2>=11, B2<=19), E2*0.7, IF(AND(B2>=20, B2<=29), E2*0.675, IF(AND(B2>=30, B2<=39), E2*0.65,"")))))`

As one final component of your formula, you need to decide what to do when none of the conditions are met. In this example, we have returned “” when the value in B2 does not meet any of the IF conditions above.

Credit: http://www.techonthenet.com/excel/formulas/if.php